Sign in to follow this  
Jonnie Wilson

Big Bertha

11 posts in this topic

After spending way too much trying to get enough light from white light led arrays for my DXG125 video cams I had conceded defeat...or I thought I had until I saw the white light go pro builds on here.

I got two 36watt flood led arrays for $34, put one at the top of a 1060 case and the second at the bottom. Nothing petite about this build that's for sure and pretty hard to camo the reflectors.

I got a sla battery from a recycler for $4 that was a used as a backup for something and is like brand new. I liquid nailed and camoed the battery and will hang it off the python cable. Testing in the garage I got 38 3 minute videos and the battery was still reading over 11 volts. Not sure what the amp hour rating of the battery is. Very bright in the garage but time will tell how it goes in the bush. I'll set it up over Easter for a proper test.

Resized_20180325_154904.jpeg

Resized_20180325_154942_1.jpeg

Share this post


Link to post
Share on other sites
 
 
7 hours ago, Badgerbuckhunter said:

Good luck. Do you normally set your videos for 3 minute record?

Yes for deer I use a 3 minute record, for kangaroos and birds I go for 30 seconds. 

Share this post


Link to post
Share on other sites
 

Good luck with it Jonnie, I hope it works out for you. I bought a couple of the 36 watt flood lights for my GoPro and tested one of them running on four 18650 batteries. The 18650s didn't hold up for long (less than 12 one minute videos) so I was thinking of trying a 12 volt 7.2 amp hour SLA that I have.

Share this post


Link to post
Share on other sites
 

Yes i think the SLA is the only way to go for the 36 watt arrays. If i test my battery with the 2 arrays on it still puts out over 10 volts after 34 3 minute videos. After 38 videos it was holding 9.4 volts with both arrays on.

Ralph do you know if a code could be written to record for say 3 minutes in daylight and once dark is detected and the array is activated to record for a shorter time? 

56 minutes ago, bigbassmann said:

Good luck with it Jonnie, I hope it works out for you. I bought a couple of the 36 watt flood lights for my GoPro and tested one of them running on four 18650 batteries. The 18650s didn't hold up for long (less than 12 one minute videos) so I was thinking of trying a 12 volt 7.2 amp hour SLA that I have.

 

Share this post


Link to post
Share on other sites
 

Yes a code can be written to do that.

Share this post


Link to post
Share on other sites
 

Jim would you be able to modify one or your dxg125 codes to record for 3 minutes during daylight and 1 1/2 minutes once dark?

Thank you.

Share this post


Link to post
Share on other sites
 

Sure

Share this post


Link to post
Share on other sites
 
#REM
PROGRAM FOR THE GEN2.0 VIDEO BOARD FOR JOHNNIE WILSON
DIP 1 CONTROLS THE VIDEO LENGTH DURING THE DAY OFF = 1 1/2 MINUTES  ON = 3 MINUTES
DIP 2 CONTROLS THE VIDEO LENGTH AT NIGHT  OFF = 1 1/2 MINUTES  ON = 3 MINUTES
DIPS 3 AND 4 CONTROLS THE SHUTTER DELAY FOR THE DXG125
The Array plugs in to Output 1
The Mic Preamp plugs into Output 2
#ENDREM

SYMBOL CDSREAD = C.0
SYMBOL CDSPWR = C.1
SYMBOL PIRINPUT = PINC.2
SYMBOL SPOTLIGHT = C.3
SYMBOL SERIALIN = PINC.4
SYMBOL DIP4 = PINC.5
SYMBOL CAMPWR = C.6
SYMBOL LED = C.7
SYMBOL DIP3 = PINB.0
SYMBOL DIP2 = PINB.1
SYMBOL DIP1 = PINB.2
SYMBOL OUT4 = B.3
SYMBOL CAMSHT = B.4
SYMBOL OUT3 = B.5
SYMBOL MIC = B.6
SYMBOL OPTO2 = B.7

'List Outputs and make them low
Low CDSPWR
Low SPOTLIGHT
Low CAMPWR
Low LED
Low OUT4
Low OPTO2
Low OUT3
Low MIC
Low CAMSHT
' List Inputs
Input C.2	'PIR INPUT
Input C.4	'SERIAL IN FOR PROGRAMMING
Input C.5	'DIP 4 INPUT
Input B.0	'DIP 3 INPUT
Input B.1	'DIP 2 INPUT
Input B.2	'DIP 1 INPUT

'list Bit Variables
Symbol DayStatus = bit0
Symbol SpotLightOn = bit1
'list Byte Variables
Symbol LightLevel = b4
Symbol DaySetting = b5
Symbol NightSetting = b6
Symbol Counter = b7
'list Word Variables
Symbol DayRecordTime = w7
Symbol NightRecordTime = w8
Symbol ShutterDelay = w9
Symbol WalkTestTimer = w10
Symbol CheckCDSTimer = w11

Disablebod 
'Set default variable settings
DayStatus = 1
DaySetting = 30
NightSetting = 20
WalkTestTimer = 0 
CheckCDSTimer = 0 
Nap 5	'let power settle so we can check the dip switch settings
If Dip1 = 1 Then	'Dip 1 is Off so 1 1/2 minute video length
	DayRecordTime = 40
ElseIf Dip1 = 0 Then	'Dip 1 is On so 3 minute video length
	DayRecordTime = 78
EndIf
Nap 5	'let power settle so we can check dip 2
If Dip2 = 1 Then	'Dip 2 is Off so 1 1/2 minute video length
	NightRecordTime = 40
ElseIf Dip2 = 0 Then	'Dip 2 is On so run in TrailMaster Mode
	NightRecordTime = 78
EndIf
Nap 5	'let power settle so we can check dips 3 and 4 for Shutter Delay for the DXG125
If Dip3 = 1 and Dip4 = 1 Then
	ShutterDelay = 600
ElseIf Dip3 = 1 and Dip4 = 0 Then
	ShutterDelay = 900
ElseIf Dip3 = 0 and Dip4 = 1 Then
	ShutterDelay = 1200 
ElseIf Dip3 = 0 and Dip4 = 0 Then
	ShutterDelay = 2000
EndIf
Nap 5 
'turn on the camera and test everything 
High LED
Pause 1000
High SpotLight
Pause 1000
High CamPwr
Pause 1000
Low CamPwr
Sleep 5
High CamPwr
Pause 1000
Low CamPwr
Pause 1000
Low SpotLight
Pause 1000
Low LED
Pause 2000
Nap 5	'let power settle so we can check the cds and see if it is daytime or night outside
High       CdsPwr  ' apply power to CDS sensor
Nap 5     ' allow power to settle
Readadc                CdsRead, LightLevel
Low CdsPwr
If LightLevel < NightSetting Then
      DayStatus = 0
	Pause 1000
EndIf
If LightLevel >= DaySetting Then
	DayStatus = 1
	Pause 1000
EndIf
CheckCDSTimer = 0 
Nap 3

WalkTest:

If PirInput = 1 then
      High LED
      Nap 6        'pause low power for 1.1 seconds
      Low LED
      Nap 8        'pause low power for 4 seconds
      WalkTestTimer = 0
EndIf
If WalkTestTimer >= 210 then     'approx 30 seconds 
      Let b8 = 10
      For Counter = 1 to b8
	High LED
	Pause 200
	Low LED
	Pause 200
	Next Counter
      Pause 1000
	SetInt %00000100,%00000100
      GoTo MainProgramLoop
EndIf
WalkTestTimer = WalkTestTimer + 1
Nap 3
GoTo WalkTest 

MainProgramLoop:

CheckCDSTimer = CheckCDSTimer + 1
If CheckCDSTimer >= 2080 Then             ' check time every 5 minutes
  	High       CdsPwr                    ' apply power to CDS sensor
     	Nap 5     ' allow power to settle
      Readadc                CdsRead, LightLevel
      Low CdsPwr
      If LightLevel >= DaySetting Then
          	DayStatus = 1
           	CheckCDSTimer = 0
		Pause 1000
	Endif
	If LightLevel < NightSetting Then
		DayStatus = 0 
		CheckCDSTimer = 0
		Pause 1000
	EndIf
EndIf

Nap 3
GoTo MainProgramLoop

Interrupt:
High Mic			'turn on the mic preamp
If DayStatus = 0 Then	'its dark outside so turn on the led array
	High SpotLight
	SpotLightOn = 1
EndIf
High CamPwr			'turn on the camera
Pause 1000
Low CamPwr
Pause ShutterDelay
High CamSht			'push the shutter to start recording video
Pause 1300
Low CamSht
If DayStatus = 1 Then	'get the length of video desired from dip switch settings
	Sleep DayRecordTime
ElseIf DayStatus = 0 Then
	Sleep NightRecordTime
EndIf
High CamSht			'stop recording the video
Pause 2000
Low CamSht
If SpotLightOn = 1 Then	'turn the array off if it was on
	Low SpotLight
	SpotLightOn = 0 
EndIf
Low Mic		'turn off the mic preamp
High CamPwr		'turn off the camera
Pause 1000
Low CamPwr
Nap 3
SetInt %00000100,%00000100	'reset the interrupt for the pir sensor
Return

 

Edited by Firemanjim

Share this post


Link to post
Share on other sites
 

There is your code Johnnie

 

Share this post


Link to post
Share on other sites
 

Thanks Jim I appreciate what you have done for me. 

I will try and load the code when I get back home after Easter and will let you know how it goes. 

Share this post


Link to post
Share on other sites
 

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this